home *** CD-ROM | disk | FTP | other *** search
/ Compendium Deluxe 2 / LSD and 17bit Compendium Deluxe - Volume II.iso / a / prog / misc / xes120.lha / XES / REXX / MultiFiles.xdme < prev    next >
Text File  |  1994-11-09  |  5KB  |  155 lines
  1. /* MultiFiles.dme: Uses the ReqTools File Requester to delete, crunch,
  2.    decrunch, copy, move, print, or load multiple files */
  3. /* Copyright © 1994 Fergus Duniho */
  4.  
  5. if ~show("L","rexxreqtools.library") then
  6.     if ~addlib("rexxreqtools.library",0,-30) then exit
  7.  
  8. if ~show("L","rexxarplib.library") then
  9.     if ~addlib("rexxarplib.library",0,-30) then exit
  10.  
  11. parse arg com .
  12.  
  13. select
  14.     when com = "ViewArc" then do
  15.         hailstr = "Select Archives to View"
  16.         oktext = "_View"
  17.     end
  18.     when com = "Unarchive" then do
  19.         hailstr = "Select Archives to Extract"
  20.         oktext = "_Extract"
  21.     end
  22.     otherwise do
  23.         hailstr = "Select Files to" com
  24.         oktext = "_" || com
  25.     end
  26. end
  27. tagstr = "rt_reqpos=reqpos_centerscr rtfi_flags=freqf_multiselect|freqf_patgad"
  28. if com = "Delete" then tagstr = tagstr || "|freqf_selectdirs|freqf_save"
  29. address 'XDME.1'
  30. options results
  31. 'rxresult $path'
  32. P = result
  33. 'rxresult $fname'
  34. N = result
  35.  
  36. if com = "ViewArc" | com = "Unarchive" then do
  37.     P = "Misc:Archives"
  38.     N = ""
  39. end
  40.  
  41. call rtfilerequest(P,N,hailstr,oktext,tagstr,files)
  42. If files = 0 Then Exit
  43.  
  44. Select
  45.     When com = "Delete" Then Do X = 1 to files.count
  46.         Call Remove files.X
  47.     End
  48.     When com = "Unpack" Then Do X = 1 to files.count
  49.         C = 'xpack "' || files.X || '"'
  50.         Say "Unpacking" files.X "..."
  51.         Address Command C
  52.     End
  53.     When com = "Copy" | com = "Move" Then Do
  54.         if files.count = 1 then do
  55.             tagstr = "rt_reqpos=reqpos_centerscr rtfi_flags=freqf_patgad"
  56.             dest = rtfilerequest(P,N,"Select Destination",,tagstr)
  57.         end
  58.         else do
  59.             tagstr = "rt_reqpos=reqpos_centerscr rtfi_flags=freqf_nofiles"
  60.             dest = rtfilerequest(P,,"Select Destination",,tagstr)
  61.         end
  62.         if rtresult = 1 then do
  63.             do X = 1 to files.count
  64.                 C = com '"' || files.X || '" "' || dest || '"'
  65.                 Say C
  66.                 Address Command C
  67.             End
  68.         End
  69.     End
  70.     When com = "Print" Then Do
  71.         D = Request(22,19,"Select Destination", "PRT:", " Print ", " Cancel ")
  72.         If D ~= "" Then Do
  73.             Do X = 1 to files.count
  74.                 C = 'Type "' || files.X || '" to "' || D || '"'
  75.                 Say C
  76.                 Address Command C
  77.             End
  78.         End
  79.     End
  80.     When com = "Run" Then Do X = 1 to files.count
  81.         C = 'runback "' || files.X || '"'
  82.         Say C
  83.         Address Command C
  84.     End
  85.     When com = "Load" Then Do X = 1 to files.count
  86.             C = "newwindow newfile (" || files.X || ") mw+"
  87.             C
  88.     End
  89.     When com = "Unarchive" Then Do
  90.         tagstr = "rt_reqpos=reqpos_centerscr rtfi_flags=freqf_nofiles|freqf_save"
  91.         dest = rtfilerequest(P,,"Select Destination",,tagstr)
  92.         if rtresult = 1 then do
  93.             do X = 1 to files.count
  94.                 tail = upper(right(files.X, 3))
  95.                 select
  96.                     when tail = "LHA" | tail = "LZH" | tail = "RUN" then
  97.                         unarc = 'tools:compression/lha -m -a x "' || files.X || '"' '"' || dest || '"'
  98.                     when tail = "ZIP" then
  99.                         unarc = 'tools:compression/unzip -o "' || files.X || '"'
  100.                     when tail = "ZOO" then
  101.                         unarc = 'tools:compression/zoo x./ "' || files.X || '"'
  102.                     otherwise iterate
  103.                 end
  104.                 Say unarc
  105.                 Address Command unarc
  106.             End
  107.         End
  108.     End
  109.     When com = "ViewArc" Then Do
  110.         Call Delete 'T:Archives'
  111.         Do X = 1 to files.count
  112.             tail = upper(right(files.X, 3))
  113.             select
  114.                 when tail = "LHA" | tail = "LZH" | tail = "RUN" then
  115.                     view = 'tools:compression/lha >>T:Archives v'
  116.                 when tail = "ZIP" then
  117.                     view = 'tools:compression/unzip >>T:Archives -v'
  118.                 when tail = "ZOO" then
  119.                     view = 'tools:compression/zoo >>T:Archives -list'
  120.                 otherwise iterate
  121.             end
  122.             C = 'execute (' || view '"' || files.X || '")'
  123.             C
  124.         End
  125.         'execute (C:runback SYS:Utilities/Most T:Archives)'
  126.     End
  127.     Otherwise Do X = 1 to files.count
  128.         C = 'xpack "' || files.X || '" method' com
  129.         Say "Packing" files.X "with" com "compression ..."
  130.         Address Command C
  131.     End
  132. End
  133. Exit
  134.  
  135. Remove: Procedure
  136.     parse arg fname
  137.     if word(statef(fname), 1) = "DIR" then do
  138.         call filelist(Pattern(fname), files, , "E")
  139.         do x = 1 to files.0
  140.             Call Remove files.x
  141.         end
  142.     end
  143.     Say "Deleting" fname "..."
  144.     call delete fname
  145.     call delete fname || ".info"
  146. return
  147.  
  148. Pattern: Procedure
  149.     parse arg dir
  150.     if right(dir, 1) ~= ":" then
  151.         pat = dir || "/*"
  152.     else
  153.         pat = dir || "*"
  154. return pat
  155.